PitPresaIFTTT

PitPresaIFTTT, presa elettrica con realay ESP8266 comandata tramite IFTTT.

PitPresaIFTTT è una evoluzione di PitPresa e sfrutta IFTTT attraverso il servizio MQTT io.adafruit.com. In questo modo viene azionato un pin che attiva o disattiva un relay a sua volta collegato ad una presa elettrica. All'interno del contenitore (presa) trovano spazio il modulo di alimentazione HLK-PM01 (220V --> 5V) e il modulo relay predisposto per l'ESP-01.

Il codice è ripreso dal sito esperienzahitech.it dove sono indicati tutti i passaggi sia lato IFTTT che IO.Adafruit.

Cosa serve:

• ESp8266 - ESP-01
• Modulo Relay per ESP-01
• Contenitore presa
• Modulo di alimentazione HLK-PM01
• Spina elettrica
• cavetti

Codice sorgente:

/*

	PitPresa
	
	   Zappoco  - PitPresa_20_05_01   02/05/2020 -- Adattamento di http://www.esperienzahitech.it/iot/apriamo-il-portone-con-google-assistant-esp01/
	   Zappoco  - PitPresa_19_11_02   04/11/2019 -- Adattamento di https://lastminuteengineers.com/creating-esp8266-web-server-arduino-ide/
	   Zappoco  - PitPresa_19_11_01   02/11/2019 -- Adattamento di ESP-01_LedControWeb (Prof. Michele Maffucci)


 */

#include "ESP8266WiFi.h"
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

// const int pinLed1 = D0;

#define LED_PIN 0             //per ESP-01
//#define LED_PIN D0          //per D1 Mini

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "...your SSID..."
#define WLAN_PASS       "...your password..."

/************************* Adafruit.io Setup *********************************/

#define AIO_SERVER      "io.adafruit.com"
#define AIO_SERVERPORT  1883                   // use 8883 for SSL

#define AIO_USERNAME    "...your AIO username (see https://accounts.adafruit.com)..."
#define AIO_KEY         "...your AIO key..."


/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;
// or... use WiFiFlientSecure for SSL
//WiFiClientSecure client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);

/****************************** Feeds ***************************************/
// Setup a feed called 'open-door' for subscribing to changes.
// Adafruit_MQTT_Subscribe pitPresaFeed = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/open-door");
Adafruit_MQTT_Subscribe pitPresaFeed = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/PitPresa");

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

void setup() {
  Serial.begin(115200);
  delay(10);

  Serial.println(F("Adafruit MQTT demo"));

  //pin output
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);   
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

  // Setup MQTT subscription for onoff feed.
  mqtt.subscribe(&pitPresaFeed);
}

uint32_t x=0;

void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // this is our 'wait for incoming subscription packets' busy subloop
  // try to spend your time here

  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(5000))) {
    if (subscription == &pitPresaFeed) {
      Serial.print(F("Got: "));
      Serial.println((char *)pitPresaFeed.lastread);
      //openDoor();
      String lastValueRead = (char *)pitPresaFeed.lastread;
      Serial.print(F("Got String: "));
      Serial.println(lastValueRead );
      if ( lastValueRead == "on") {
         Serial.println("led on");
         digitalWrite(LED_PIN, HIGH);
      } else {
         Serial.println("led off");
         digitalWrite(LED_PIN, LOW);
      }
    }
  }

  // ping the server to keep the mqtt connection alive
  // NOT required if you are publishing once every KEEPALIVE seconds
  if(! mqtt.ping()) {
    mqtt.disconnect();
  }
}

/*
void openDoor() {
  digitalWrite(LED_PIN, HIGH);
  delay(1000);
  digitalWrite(LED_PIN, LOW);
}
*/

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
}

Scarica tutto quello che serve: